10 PRINT CHR$(11) : REM SCREEN CLEAR
20 DIM A(25),R(77)
30 PRINT "THIS PROGRAM IS DESIGNED TO SELECT THE"
40 PRINT "PROPER VALUES OF RESISTANCE AND CAPA-"
50 PRINT "CITANCE FOR THE PROPER OPERATION OF THE"
60 PRINT "567 TONE DECODER."
70 PRINT
80 PRINT "ENTER THE DESIRED FREQUENCY OF OPERATION"
90 INPUT F
100 PRINT CHR$(11)
110 PRINT
120 S=1
130 FOR I=1 TO 13
140 READ A(I)
150 NEXT I
160 PRINT
170 PRINT "THE FOLLOWING VALUES OF RESISTANCE"
180 PRINT "AND CAPACITANCE DETERMINE THE FRE-"
190 PRINT "QUENCY OF";F;"HZ"
200 A=1
210 FOR J=2 TO 7
220 FOR I=3 TO 13
230 R(A)=A(I)*10 ^ J
240 A=A+1
250 NEXT I
260 NEXT J
270 FOR A=1 TO 66
280 C=1/(R(A)*F)
290 IF C<10^(-9) THEN 390
300 FOR H=1 TO 9
310 D=C/10^(-H)
320 IF 1>D THEN 340
330 IF D<10 THEN 350
340 NEXT H
350 FOR I=1 TO 6
360 IF .95*A(I)>D THEN 380
370 IF D<1.05*A(I) THEN 410
380 NEXT I
390 NEXT A
400 GOTO 500
410 PRINT
420 PRINT
430 PRINT "SET";S;":"
440 PRINT "R1 =";R(A);"OHMS"
450 PRINT "C1 =";1E+06*C;"UF"
460 S=S+1
470 PRINT
480 GOTO 390
490 DATA 5.0,10.0,1.0,2.2,3.3,4.7,1.2,1.5,1.8,3.9,5.6,6.2,8.2
500 END
